Mercurial > hg > orthanc

comparison Resources/CMake/DcmtkConfigurationStatic-3.6.2.cmake @ 3274:95b0536be2c3

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
preparing for dcmtk 3.6.4
author Sebastien Jodogne <s.jodogne@gmail.com>
date Wed, 20 Feb 2019 17:19:27 +0100
parents
children dd10fe965870
comparison
equal deleted inserted replaced
3273:45786a7c3735 3274:95b0536be2c3
1 SET(DCMTK_VERSION_NUMBER 362)
2 SET(DCMTK_PACKAGE_VERSION "3.6.2")
3 SET(DCMTK_SOURCES_DIR ${CMAKE_BINARY_DIR}/dcmtk-3.6.2)
4 SET(DCMTK_URL "http://orthanc.osimis.io/ThirdPartyDownloads/dcmtk-3.6.2.tar.gz")
5 SET(DCMTK_MD5 "d219a4152772985191c9b89d75302d12")
6
7 macro(DCMTK_UNSET)
8 endmacro()
9
10 macro(DCMTK_UNSET_CACHE)
11 endmacro()
12
13 set(DCMTK_BINARY_DIR ${DCMTK_SOURCES_DIR}/)
14 set(DCMTK_CMAKE_INCLUDE ${DCMTK_SOURCES_DIR}/)
15 set(DCMTK_WITH_THREADS ON)
16
17 add_definitions(-DDCMTK_INSIDE_LOG4CPLUS=1)
18
19 if (IS_DIRECTORY "${DCMTK_SOURCES_DIR}")
20 set(FirstRun OFF)
21 else()
22 set(FirstRun ON)
23 endif()
24
25 DownloadPackage(${DCMTK_MD5} ${DCMTK_URL} "${DCMTK_SOURCES_DIR}")
26
27
28 if (FirstRun)
29 # "3.6.2 CXX11 fails on Linux; patch suggestions included"
30 # https://forum.dcmtk.org/viewtopic.php?f=3&t=4637
31 message("Applying patch to detect mathematic primitives in DCMTK 3.6.2 with C++11")
32 execute_process(
33 COMMAND ${PATCH_EXECUTABLE} -p0 -N -i
34 ${ORTHANC_ROOT}/Resources/Patches/dcmtk-3.6.2-cmath.patch
35 WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
36 RESULT_VARIABLE Failure
37 )
38
39 if (Failure)
40 message(FATAL_ERROR "Error while patching a file")
41 endif()
42 else()
43 message("The patches for DCMTK have already been applied")
44 endif()
45
46
47 # C_CHAR_UNSIGNED *must* be set before calling "GenerateDCMTKConfigure.cmake"
48 IF (CMAKE_CROSSCOMPILING)
49 if (CMAKE_COMPILER_IS_GNUCXX AND
50 CMAKE_SYSTEM_NAME STREQUAL "Windows") # MinGW
51 SET(C_CHAR_UNSIGNED 1 CACHE INTERNAL "Whether char is unsigned.")
52
53 elseif(CMAKE_SYSTEM_NAME STREQUAL "Emscripten") # WebAssembly or asm.js
54
55 # Check out "../WebAssembly/ArithmeticTests/" to regenerate the
56 # "arith.h" file
57 configure_file(
58 ${ORTHANC_ROOT}/Resources/WebAssembly/arith.h
59 ${DCMTK_SOURCES_DIR}/config/include/dcmtk/config/arith.h
60 COPYONLY)
61
62 UNSET(C_CHAR_UNSIGNED CACHE)
63 SET(C_CHAR_UNSIGNED 0 CACHE INTERNAL "")
64
65 else()
66 message(FATAL_ERROR "Support your platform here")
67 endif()
68 ENDIF()
69
70
71 if ("${CMAKE_SYSTEM_VERSION}" STREQUAL "LinuxStandardBase")
72 SET(DCMTK_ENABLE_CHARSET_CONVERSION "iconv" CACHE STRING "")
73 SET(HAVE_SYS_GETTID 0 CACHE INTERNAL "")
74
75 execute_process(
76 COMMAND ${PATCH_EXECUTABLE} -p0 -N -i
77 ${ORTHANC_ROOT}/Resources/Patches/dcmtk-3.6.2-linux-standard-base.patch
78 WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
79 RESULT_VARIABLE Failure
80 )
81
82 if (FirstRun AND Failure)
83 message(FATAL_ERROR "Error while patching a file")
84 endif()
85 endif()
86
87 SET(DCMTK_SOURCE_DIR ${DCMTK_SOURCES_DIR})
88 include(${DCMTK_SOURCES_DIR}/CMake/CheckFunctionWithHeaderExists.cmake)
89 include(${DCMTK_SOURCES_DIR}/CMake/GenerateDCMTKConfigure.cmake)
90
91
92 if (CMAKE_SYSTEM_NAME STREQUAL "Emscripten") # WebAssembly or
93 # asm.js The macros below are not properly discovered by DCMTK
94 # when using WebAssembly. Check out "../WebAssembly/arith.h" for
95 # how we produced these values. This step MUST be after
96 # "GenerateDCMTKConfigure" and before the generation of
97 # "osconfig.h".
98 UNSET(SIZEOF_VOID_P CACHE)
99 UNSET(SIZEOF_CHAR CACHE)
100 UNSET(SIZEOF_DOUBLE CACHE)
101 UNSET(SIZEOF_FLOAT CACHE)
102 UNSET(SIZEOF_INT CACHE)
103 UNSET(SIZEOF_LONG CACHE)
104 UNSET(SIZEOF_SHORT CACHE)
105 UNSET(SIZEOF_VOID_P CACHE)
106
107 SET(SIZEOF_VOID_P 4 CACHE INTERNAL "")
108 SET(SIZEOF_CHAR 1 CACHE INTERNAL "")
109 SET(SIZEOF_DOUBLE 8 CACHE INTERNAL "")
110 SET(SIZEOF_FLOAT 4 CACHE INTERNAL "")
111 SET(SIZEOF_INT 4 CACHE INTERNAL "")
112 SET(SIZEOF_LONG 4 CACHE INTERNAL "")
113 SET(SIZEOF_SHORT 2 CACHE INTERNAL "")
114 SET(SIZEOF_VOID_P 4 CACHE INTERNAL "")
115 endif()
116
117
118 set(DCMTK_PACKAGE_VERSION_SUFFIX "")
119 set(DCMTK_PACKAGE_VERSION_NUMBER ${DCMTK_VERSION_NUMBER})
120
121 CONFIGURE_FILE(
122 ${DCMTK_SOURCES_DIR}/CMake/osconfig.h.in
123 ${DCMTK_SOURCES_DIR}/config/include/dcmtk/config/osconfig.h)
124
125 if (${CMAKE_SYSTEM_NAME} STREQUAL "Windows")
126 link_libraries(netapi32) # For NetWkstaUserGetInfo@12
127 link_libraries(iphlpapi) # For GetAdaptersInfo@8
128
129 # Configure Wine if cross-compiling for Windows
130 if (CMAKE_COMPILER_IS_GNUCXX)
131 include(${DCMTK_SOURCES_DIR}/CMake/dcmtkUseWine.cmake)
132 FIND_PROGRAM(WINE_WINE_PROGRAM wine)
133 FIND_PROGRAM(WINE_WINEPATH_PROGRAM winepath)
134 list(APPEND DCMTK_TRY_COMPILE_REQUIRED_CMAKE_FLAGS "-DCMAKE_EXE_LINKER_FLAGS=-static")
135 endif()
136 endif()
137
138 # This step must be after the generation of "osconfig.h"
139 if (NOT CMAKE_SYSTEM_NAME STREQUAL "Emscripten")
140 INSPECT_FUNDAMENTAL_ARITHMETIC_TYPES()
141 endif()
142
143 AUX_SOURCE_DIRECTORY(${DCMTK_SOURCES_DIR}/dcmdata/libsrc DCMTK_SOURCES)
144 AUX_SOURCE_DIRECTORY(${DCMTK_SOURCES_DIR}/ofstd/libsrc DCMTK_SOURCES)
145
146 if (ENABLE_DCMTK_NETWORKING)
147 AUX_SOURCE_DIRECTORY(${DCMTK_SOURCES_DIR}/dcmnet/libsrc DCMTK_SOURCES)
148 include_directories(
149 ${DCMTK_SOURCES_DIR}/dcmnet/include
150 )
151 endif()
152
153 if (ENABLE_DCMTK_JPEG)
154 AUX_SOURCE_DIRECTORY(${DCMTK_SOURCES_DIR}/dcmjpeg/libsrc DCMTK_SOURCES)
155 AUX_SOURCE_DIRECTORY(${DCMTK_SOURCES_DIR}/dcmjpeg/libijg8 DCMTK_SOURCES)
156 AUX_SOURCE_DIRECTORY(${DCMTK_SOURCES_DIR}/dcmjpeg/libijg12 DCMTK_SOURCES)
157 AUX_SOURCE_DIRECTORY(${DCMTK_SOURCES_DIR}/dcmjpeg/libijg16 DCMTK_SOURCES)
158 include_directories(
159 ${DCMTK_SOURCES_DIR}/dcmjpeg/include
160 ${DCMTK_SOURCES_DIR}/dcmjpeg/libijg8
161 ${DCMTK_SOURCES_DIR}/dcmjpeg/libijg12
162 ${DCMTK_SOURCES_DIR}/dcmjpeg/libijg16
163 ${DCMTK_SOURCES_DIR}/dcmimgle/include
164 )
165 list(REMOVE_ITEM DCMTK_SOURCES
166 ${DCMTK_SOURCES_DIR}/dcmjpeg/libsrc/ddpiimpl.cc
167
168 # Disable support for encoding JPEG (modification in Orthanc 1.0.1)
169 ${DCMTK_SOURCES_DIR}/dcmjpeg/libsrc/djcodece.cc
170 ${DCMTK_SOURCES_DIR}/dcmjpeg/libsrc/djencsv1.cc
171 ${DCMTK_SOURCES_DIR}/dcmjpeg/libsrc/djencbas.cc
172 ${DCMTK_SOURCES_DIR}/dcmjpeg/libsrc/djencpro.cc
173 ${DCMTK_SOURCES_DIR}/dcmjpeg/libsrc/djenclol.cc
174 ${DCMTK_SOURCES_DIR}/dcmjpeg/libsrc/djencode.cc
175 ${DCMTK_SOURCES_DIR}/dcmjpeg/libsrc/djencext.cc
176 ${DCMTK_SOURCES_DIR}/dcmjpeg/libsrc/djencsps.cc
177 )
178 endif()
179
180
181 if (ENABLE_DCMTK_JPEG_LOSSLESS)
182 AUX_SOURCE_DIRECTORY(${DCMTK_SOURCES_DIR}/dcmjpls/libsrc DCMTK_SOURCES)
183 AUX_SOURCE_DIRECTORY(${DCMTK_SOURCES_DIR}/dcmjpls/libcharls DCMTK_SOURCES)
184 include_directories(
185 ${DCMTK_SOURCES_DIR}/dcmjpeg/include
186 ${DCMTK_SOURCES_DIR}/dcmjpls/include
187 ${DCMTK_SOURCES_DIR}/dcmjpls/libcharls
188 )
189 list(REMOVE_ITEM DCMTK_SOURCES
190 ${DCMTK_SOURCES_DIR}/dcmjpls/libsrc/djcodece.cc
191
192 # Disable support for encoding JPEG-LS (modification in Orthanc 1.0.1)
193 ${DCMTK_SOURCES_DIR}/dcmjpls/libsrc/djencode.cc
194 )
195 list(APPEND DCMTK_SOURCES
196 ${DCMTK_SOURCES_DIR}/dcmjpeg/libsrc/djrplol.cc
197 )
198 endif()
199
200
201 # Source for the logging facility of DCMTK
202 AUX_SOURCE_DIRECTORY(${DCMTK_SOURCES_DIR}/oflog/libsrc DCMTK_SOURCES)
203 if (${CMAKE_SYSTEM_NAME} STREQUAL "Linux" OR
204 ${CMAKE_SYSTEM_NAME} STREQUAL "Darwin" OR
205 ${CMAKE_SYSTEM_NAME} STREQUAL "FreeBSD" OR
206 ${CMAKE_SYSTEM_NAME} STREQUAL "kFreeBSD" OR
207 ${CMAKE_SYSTEM_NAME} STREQUAL "OpenBSD" OR
208 ${CMAKE_SYSTEM_NAME} STREQUAL "Emscripten")
209 list(REMOVE_ITEM DCMTK_SOURCES
210 ${DCMTK_SOURCES_DIR}/oflog/libsrc/clfsap.cc
211 ${DCMTK_SOURCES_DIR}/oflog/libsrc/windebap.cc
212 ${DCMTK_SOURCES_DIR}/oflog/libsrc/winsock.cc
213 )
214
215 elseif (${CMAKE_SYSTEM_NAME} STREQUAL "Windows")
216 list(REMOVE_ITEM DCMTK_SOURCES
217 ${DCMTK_SOURCES_DIR}/oflog/libsrc/unixsock.cc
218 ${DCMTK_SOURCES_DIR}/oflog/libsrc/clfsap.cc
219 )
220 endif()
221
222
223 if (ORTHANC_SANDBOXED)
224 configure_file(
225 ${ORTHANC_ROOT}/Resources/WebAssembly/dcdict.h
226 ${DCMTK_SOURCES_DIR}/dcmdata/include/dcmtk/dcmdata/dcdict.h
227 COPYONLY)
228
229 configure_file(
230 ${ORTHANC_ROOT}/Resources/WebAssembly/dcdict.cc
231 ${DCMTK_SOURCES_DIR}/dcmdata/libsrc/dcdict.cc
232 COPYONLY)
233 endif()
234
235
236 list(REMOVE_ITEM DCMTK_SOURCES
237 ${DCMTK_SOURCES_DIR}/dcmdata/libsrc/mkdictbi.cc
238 ${DCMTK_SOURCES_DIR}/dcmdata/libsrc/mkdeftag.cc
239 )
240
241
242 #set_source_files_properties(${DCMTK_SOURCES}
243 # PROPERTIES COMPILE_DEFINITIONS
244 # "PACKAGE_VERSION=\"${DCMTK_PACKAGE_VERSION}\";PACKAGE_VERSION_NUMBER=\"${DCMTK_VERSION_NUMBER}\"")