Mercurial > hg > orthanc
annotate CMakeLists.txt @ 2865:0f07bdae0805
ImageAccessor::GetWriteableAccessor() and GetReadOnlyAccessor()
author | Sebastien Jodogne <s.jodogne@gmail.com> |
---|---|
date | Fri, 05 Oct 2018 17:56:55 +0200 |
parents | 52b017d22a4f |
children | 251614c2edac |
rev | line source |
---|---|
2691 | 1 cmake_minimum_required(VERSION 2.8) |
2 | |
3 project(Orthanc) | |
4 | |
5 | |
6 ##################################################################### | |
7 ## Generic parameters of the Orthanc framework | |
8 ##################################################################### | |
9 | |
10 include(${CMAKE_SOURCE_DIR}/Resources/CMake/OrthancFrameworkParameters.cmake) | |
11 | |
12 # Enable all the optional components of the Orthanc framework | |
13 set(ENABLE_CRYPTO_OPTIONS ON) | |
14 set(ENABLE_DCMTK ON) | |
15 set(ENABLE_DCMTK_NETWORKING ON) | |
16 set(ENABLE_GOOGLE_TEST ON) | |
17 set(ENABLE_JPEG ON) | |
18 set(ENABLE_LOCALE ON) | |
19 set(ENABLE_LUA ON) | |
20 set(ENABLE_PNG ON) | |
21 set(ENABLE_PUGIXML ON) | |
22 set(ENABLE_SQLITE ON) | |
23 set(ENABLE_WEB_CLIENT ON) | |
24 set(ENABLE_WEB_SERVER ON) | |
25 set(ENABLE_ZLIB ON) | |
26 | |
27 set(HAS_EMBEDDED_RESOURCES ON) | |
28 | |
29 | |
30 ##################################################################### | |
31 ## CMake parameters tunable at the command line to configure the | |
32 ## plugins, the companion tools, and the unit tests | |
33 ##################################################################### | |
34 | |
35 # Parameters of the build | |
36 SET(BUILD_MODALITY_WORKLISTS ON CACHE BOOL "Whether to build the sample plugin to serve modality worklists") | |
37 SET(BUILD_RECOVER_COMPRESSED_FILE ON CACHE BOOL "Whether to build the companion tool to recover files compressed using Orthanc") | |
38 SET(BUILD_SERVE_FOLDERS ON CACHE BOOL "Whether to build the ServeFolders plugin") | |
39 SET(ENABLE_PLUGINS ON CACHE BOOL "Enable plugins") | |
40 SET(UNIT_TESTS_WITH_HTTP_CONNEXIONS ON CACHE BOOL "Allow unit tests to make HTTP requests") | |
41 | |
42 | |
43 ##################################################################### | |
44 ## Configuration of the Orthanc framework | |
45 ##################################################################### | |
46 | |
47 include(${CMAKE_SOURCE_DIR}/Resources/CMake/VisualStudioPrecompiledHeaders.cmake) | |
48 include(${CMAKE_SOURCE_DIR}/Resources/CMake/OrthancFrameworkConfiguration.cmake) | |
49 | |
50 | |
51 ##################################################################### | |
52 ## List of source files | |
53 ##################################################################### | |
54 | |
55 set(ORTHANC_SERVER_SOURCES | |
56 OrthancServer/DatabaseWrapper.cpp | |
57 OrthancServer/DicomInstanceOrigin.cpp | |
58 OrthancServer/DicomInstanceToStore.cpp | |
59 OrthancServer/ExportedResource.cpp | |
60 OrthancServer/LuaScripting.cpp | |
61 OrthancServer/OrthancFindRequestHandler.cpp | |
62 OrthancServer/OrthancHttpHandler.cpp | |
63 OrthancServer/OrthancInitialization.cpp | |
64 OrthancServer/OrthancMoveRequestHandler.cpp | |
65 OrthancServer/OrthancRestApi/OrthancRestAnonymizeModify.cpp | |
66 OrthancServer/OrthancRestApi/OrthancRestApi.cpp | |
67 OrthancServer/OrthancRestApi/OrthancRestArchive.cpp | |
68 OrthancServer/OrthancRestApi/OrthancRestChanges.cpp | |
69 OrthancServer/OrthancRestApi/OrthancRestModalities.cpp | |
70 OrthancServer/OrthancRestApi/OrthancRestResources.cpp | |
71 OrthancServer/OrthancRestApi/OrthancRestSystem.cpp | |
72 OrthancServer/QueryRetrieveHandler.cpp | |
73 OrthancServer/Search/HierarchicalMatcher.cpp | |
74 OrthancServer/Search/IFindConstraint.cpp | |
75 OrthancServer/Search/ListConstraint.cpp | |
76 OrthancServer/Search/LookupIdentifierQuery.cpp | |
77 OrthancServer/Search/LookupResource.cpp | |
78 OrthancServer/Search/RangeConstraint.cpp | |
79 OrthancServer/Search/SetOfResources.cpp | |
80 OrthancServer/Search/ValueConstraint.cpp | |
81 OrthancServer/Search/WildcardConstraint.cpp | |
82 OrthancServer/ServerContext.cpp | |
83 OrthancServer/ServerEnumerations.cpp | |
84 OrthancServer/ServerIndex.cpp | |
85 OrthancServer/ServerJobs/ArchiveJob.cpp | |
86 OrthancServer/ServerJobs/DicomModalityStoreJob.cpp | |
87 OrthancServer/ServerJobs/LuaJobManager.cpp | |
2853
52b017d22a4f
New URI: "/studies/.../merge" to merge a study
Sebastien Jodogne <s.jodogne@gmail.com>
parents:
2844
diff
changeset
|
88 OrthancServer/ServerJobs/MergeStudyJob.cpp |
2691 | 89 OrthancServer/ServerJobs/Operations/DeleteResourceOperation.cpp |
90 OrthancServer/ServerJobs/Operations/ModifyInstanceOperation.cpp | |
91 OrthancServer/ServerJobs/Operations/StorePeerOperation.cpp | |
92 OrthancServer/ServerJobs/Operations/StoreScuOperation.cpp | |
93 OrthancServer/ServerJobs/Operations/SystemCallOperation.cpp | |
94 OrthancServer/ServerJobs/OrthancJobUnserializer.cpp | |
95 OrthancServer/ServerJobs/OrthancPeerStoreJob.cpp | |
96 OrthancServer/ServerJobs/ResourceModificationJob.cpp | |
2844
99863d6245b2
New URI: "/studies/.../split" to split a study
Sebastien Jodogne <s.jodogne@gmail.com>
parents:
2808
diff
changeset
|
97 OrthancServer/ServerJobs/SplitStudyJob.cpp |
2691 | 98 OrthancServer/ServerToolbox.cpp |
99 OrthancServer/SliceOrdering.cpp | |
100 ) | |
101 | |
102 | |
103 set(ORTHANC_UNIT_TESTS_SOURCES | |
104 UnitTestsSources/DicomMapTests.cpp | |
105 UnitTestsSources/FileStorageTests.cpp | |
106 UnitTestsSources/FromDcmtkTests.cpp | |
107 UnitTestsSources/MemoryCacheTests.cpp | |
108 UnitTestsSources/ImageTests.cpp | |
109 UnitTestsSources/RestApiTests.cpp | |
110 UnitTestsSources/SQLiteTests.cpp | |
111 UnitTestsSources/SQLiteChromiumTests.cpp | |
112 UnitTestsSources/ServerIndexTests.cpp | |
113 UnitTestsSources/VersionsTests.cpp | |
114 UnitTestsSources/ZipTests.cpp | |
115 UnitTestsSources/LuaTests.cpp | |
116 UnitTestsSources/MultiThreadingTests.cpp | |
117 UnitTestsSources/UnitTestsMain.cpp | |
118 UnitTestsSources/ImageProcessingTests.cpp | |
119 UnitTestsSources/JpegLosslessTests.cpp | |
120 UnitTestsSources/StreamTests.cpp | |
121 ) | |
122 | |
123 | |
124 if (ENABLE_PLUGINS) | |
125 list(APPEND ORTHANC_SERVER_SOURCES | |
126 Plugins/Engine/OrthancPluginDatabase.cpp | |
127 Plugins/Engine/OrthancPlugins.cpp | |
128 Plugins/Engine/PluginsEnumerations.cpp | |
129 Plugins/Engine/PluginsErrorDictionary.cpp | |
2808
37583cd183ed
primitives to create jobs from plugins
Sebastien Jodogne <s.jodogne@gmail.com>
parents:
2773
diff
changeset
|
130 Plugins/Engine/PluginsJob.cpp |
2691 | 131 Plugins/Engine/PluginsManager.cpp |
132 ) | |
133 | |
134 list(APPEND ORTHANC_UNIT_TESTS_SOURCES | |
135 UnitTestsSources/PluginsTests.cpp | |
136 ) | |
137 endif() | |
138 | |
139 | |
140 if (CMAKE_COMPILER_IS_GNUCXX | |
141 AND NOT CMAKE_CROSSCOMPILING | |
142 AND USE_DCMTK_360) | |
143 # Add the "-pedantic" flag only on the Orthanc sources, and only if | |
144 # cross-compiling DCMTK 3.6.0 | |
145 set(ORTHANC_ALL_SOURCES | |
146 ${ORTHANC_CORE_SOURCES_INTERNAL} | |
147 ${ORTHANC_DICOM_SOURCES_INTERNAL} | |
148 ${ORTHANC_SERVER_SOURCES} | |
149 ${ORTHANC_UNIT_TESTS_SOURCES} | |
150 Plugins/Samples/ServeFolders/Plugin.cpp | |
151 Plugins/Samples/ModalityWorklists/Plugin.cpp | |
152 OrthancServer/main.cpp | |
153 ) | |
154 | |
155 set_source_files_properties(${ORTHANC_ALL_SOURCES} | |
156 PROPERTIES COMPILE_FLAGS -pedantic | |
157 ) | |
158 endif() | |
159 | |
160 | |
161 ##################################################################### | |
162 ## Autogeneration of files | |
163 ##################################################################### | |
164 | |
165 set(ORTHANC_EMBEDDED_FILES | |
166 PREPARE_DATABASE ${CMAKE_CURRENT_SOURCE_DIR}/OrthancServer/PrepareDatabase.sql | |
167 UPGRADE_DATABASE_3_TO_4 ${CMAKE_CURRENT_SOURCE_DIR}/OrthancServer/Upgrade3To4.sql | |
168 UPGRADE_DATABASE_4_TO_5 ${CMAKE_CURRENT_SOURCE_DIR}/OrthancServer/Upgrade4To5.sql | |
169 CONFIGURATION_SAMPLE ${CMAKE_CURRENT_SOURCE_DIR}/Resources/Configuration.json | |
170 DICOM_CONFORMANCE_STATEMENT ${CMAKE_CURRENT_SOURCE_DIR}/Resources/DicomConformanceStatement.txt | |
171 LUA_TOOLBOX ${CMAKE_CURRENT_SOURCE_DIR}/Resources/Toolbox.lua | |
172 FONT_UBUNTU_MONO_BOLD_16 ${CMAKE_CURRENT_SOURCE_DIR}/Resources/Fonts/UbuntuMonoBold-16.json | |
173 ) | |
174 | |
175 if (STANDALONE_BUILD) | |
176 # We embed all the resources in the binaries for standalone builds | |
177 add_definitions(-DORTHANC_STANDALONE=1) | |
178 EmbedResources( | |
179 ${ORTHANC_EMBEDDED_FILES} | |
180 ORTHANC_EXPLORER ${CMAKE_CURRENT_SOURCE_DIR}/OrthancExplorer | |
181 ${DCMTK_DICTIONARIES} | |
182 ) | |
183 else() | |
184 add_definitions( | |
185 -DORTHANC_STANDALONE=0 | |
186 -DORTHANC_PATH=\"${CMAKE_SOURCE_DIR}\" | |
187 ) | |
188 EmbedResources( | |
189 ${ORTHANC_EMBEDDED_FILES} | |
190 ) | |
191 endif() | |
192 | |
193 if (${CMAKE_SYSTEM_NAME} STREQUAL "Windows") | |
194 execute_process( | |
195 COMMAND | |
196 ${PYTHON_EXECUTABLE} ${ORTHANC_ROOT}/Resources/WindowsResources.py | |
197 ${ORTHANC_VERSION} Orthanc Orthanc.exe "Lightweight, RESTful DICOM server for medical imaging" | |
198 ERROR_VARIABLE Failure | |
199 OUTPUT_FILE ${AUTOGENERATED_DIR}/Orthanc.rc | |
200 ) | |
201 | |
202 if (Failure) | |
203 message(FATAL_ERROR "Error while computing the version information: ${Failure}") | |
204 endif() | |
205 | |
206 list(APPEND ORTHANC_RESOURCES ${AUTOGENERATED_DIR}/Orthanc.rc) | |
207 endif() | |
208 | |
209 | |
210 | |
211 ##################################################################### | |
212 ## Configuration of the C/C++ macros | |
213 ##################################################################### | |
214 | |
215 if (ENABLE_PLUGINS) | |
216 add_definitions(-DORTHANC_ENABLE_PLUGINS=1) | |
217 else() | |
218 add_definitions(-DORTHANC_ENABLE_PLUGINS=0) | |
219 endif() | |
220 | |
221 | |
222 if (UNIT_TESTS_WITH_HTTP_CONNEXIONS) | |
223 add_definitions(-DUNIT_TESTS_WITH_HTTP_CONNEXIONS=1) | |
224 else() | |
225 add_definitions(-DUNIT_TESTS_WITH_HTTP_CONNEXIONS=0) | |
226 endif() | |
227 | |
228 | |
229 include_directories(${CMAKE_SOURCE_DIR}/Plugins/Include) | |
230 | |
231 add_definitions( | |
232 -DORTHANC_BUILD_UNIT_TESTS=1 | |
233 -DORTHANC_ENABLE_LOGGING_PLUGIN=0 | |
234 | |
235 # Macros for the plugins | |
236 -DHAS_ORTHANC_EXCEPTION=0 | |
237 -DMODALITY_WORKLISTS_VERSION="${ORTHANC_VERSION}" | |
238 -DSERVE_FOLDERS_VERSION="${ORTHANC_VERSION}" | |
239 ) | |
240 | |
241 | |
242 # Setup precompiled headers for Microsoft Visual Studio | |
243 | |
244 # WARNING: There must be NO MORE "add_definitions()", "include()" or | |
245 # "include_directories()" below, otherwise the generated precompiled | |
246 # headers might get broken! | |
247 | |
248 if (MSVC) | |
249 add_definitions(-DORTHANC_USE_PRECOMPILED_HEADERS=1) | |
250 | |
251 set(TMP | |
252 ${ORTHANC_CORE_SOURCES_INTERNAL} | |
253 ${ORTHANC_DICOM_SOURCES_INTERNAL} | |
254 ) | |
255 | |
256 ADD_VISUAL_STUDIO_PRECOMPILED_HEADERS( | |
257 "PrecompiledHeaders.h" "Core/PrecompiledHeaders.cpp" | |
258 TMP ORTHANC_CORE_PCH) | |
259 | |
260 ADD_VISUAL_STUDIO_PRECOMPILED_HEADERS( | |
261 "PrecompiledHeadersServer.h" "OrthancServer/PrecompiledHeadersServer.cpp" | |
262 ORTHANC_SERVER_SOURCES ORTHANC_SERVER_PCH) | |
263 | |
264 ADD_VISUAL_STUDIO_PRECOMPILED_HEADERS( | |
265 "PrecompiledHeadersUnitTests.h" "UnitTestsSources/PrecompiledHeadersUnitTests.cpp" | |
266 ORTHANC_UNIT_TESTS_SOURCES ORTHANC_UNIT_TESTS_PCH) | |
267 endif() | |
268 | |
269 | |
270 | |
271 ##################################################################### | |
272 ## Build the core of Orthanc | |
273 ##################################################################### | |
274 | |
275 # "CoreLibrary" contains all the third-party dependencies and the | |
276 # content of the "Core" folder | |
277 add_library(CoreLibrary | |
278 STATIC | |
279 ${ORTHANC_CORE_PCH} | |
280 ${ORTHANC_CORE_SOURCES} | |
281 ${ORTHANC_DICOM_SOURCES} | |
282 ${AUTOGENERATED_SOURCES} | |
283 ) | |
284 | |
285 | |
286 ##################################################################### | |
287 ## Build the Orthanc server | |
288 ##################################################################### | |
289 | |
290 add_library(ServerLibrary | |
291 STATIC | |
292 ${ORTHANC_SERVER_PCH} | |
293 ${ORTHANC_SERVER_SOURCES} | |
294 ) | |
295 | |
296 # Ensure autogenerated code is built before building ServerLibrary | |
297 add_dependencies(ServerLibrary CoreLibrary) | |
298 | |
299 add_executable(Orthanc | |
300 OrthancServer/main.cpp | |
301 ${ORTHANC_RESOURCES} | |
302 ) | |
303 | |
304 target_link_libraries(Orthanc ServerLibrary CoreLibrary ${DCMTK_LIBRARIES}) | |
305 | |
306 install( | |
307 TARGETS Orthanc | |
308 RUNTIME DESTINATION sbin | |
309 ) | |
310 | |
311 | |
312 ##################################################################### | |
313 ## Build the unit tests | |
314 ##################################################################### | |
315 | |
316 add_executable(UnitTests | |
317 ${GOOGLE_TEST_SOURCES} | |
318 ${ORTHANC_UNIT_TESTS_PCH} | |
319 ${ORTHANC_UNIT_TESTS_SOURCES} | |
320 ) | |
321 | |
322 target_link_libraries(UnitTests | |
323 ServerLibrary | |
324 CoreLibrary | |
325 ${DCMTK_LIBRARIES} | |
326 ${GOOGLE_TEST_LIBRARIES} | |
327 ) | |
328 | |
329 | |
330 ##################################################################### | |
331 ## Build the "ServeFolders" plugin | |
332 ##################################################################### | |
333 | |
334 if (ENABLE_PLUGINS AND BUILD_SERVE_FOLDERS) | |
335 if (${CMAKE_SYSTEM_NAME} STREQUAL "Windows") | |
336 execute_process( | |
337 COMMAND | |
338 ${PYTHON_EXECUTABLE} ${ORTHANC_ROOT}/Resources/WindowsResources.py | |
339 ${ORTHANC_VERSION} ServeFolders ServeFolders.dll "Orthanc plugin to serve additional folders" | |
340 ERROR_VARIABLE Failure | |
341 OUTPUT_FILE ${AUTOGENERATED_DIR}/ServeFolders.rc | |
342 ) | |
343 | |
344 if (Failure) | |
345 message(FATAL_ERROR "Error while computing the version information: ${Failure}") | |
346 endif() | |
347 | |
348 list(APPEND SERVE_FOLDERS_RESOURCES ${AUTOGENERATED_DIR}/ServeFolders.rc) | |
349 endif() | |
350 | |
351 add_library(ServeFolders SHARED | |
352 ${BOOST_SOURCES} | |
353 ${JSONCPP_SOURCES} | |
354 ${LIBICONV_SOURCES} | |
355 Plugins/Samples/ServeFolders/Plugin.cpp | |
356 Plugins/Samples/Common/OrthancPluginCppWrapper.cpp | |
357 ${SERVE_FOLDERS_RESOURCES} | |
358 ) | |
359 | |
360 set_target_properties( | |
361 ServeFolders PROPERTIES | |
362 VERSION ${ORTHANC_VERSION} | |
363 SOVERSION ${ORTHANC_VERSION} | |
364 ) | |
365 | |
366 install( | |
367 TARGETS ServeFolders | |
368 RUNTIME DESTINATION lib # Destination for Windows | |
369 LIBRARY DESTINATION share/orthanc/plugins # Destination for Linux | |
370 ) | |
371 endif() | |
372 | |
373 | |
374 | |
375 ##################################################################### | |
376 ## Build the "ModalityWorklists" plugin | |
377 ##################################################################### | |
378 | |
379 if (ENABLE_PLUGINS AND BUILD_MODALITY_WORKLISTS) | |
380 if (${CMAKE_SYSTEM_NAME} STREQUAL "Windows") | |
381 execute_process( | |
382 COMMAND | |
383 ${PYTHON_EXECUTABLE} ${ORTHANC_ROOT}/Resources/WindowsResources.py | |
384 ${ORTHANC_VERSION} ModalityWorklists ModalityWorklists.dll "Sample Orthanc plugin to serve modality worklists" | |
385 ERROR_VARIABLE Failure | |
386 OUTPUT_FILE ${AUTOGENERATED_DIR}/ModalityWorklists.rc | |
387 ) | |
388 | |
389 if (Failure) | |
390 message(FATAL_ERROR "Error while computing the version information: ${Failure}") | |
391 endif() | |
392 | |
393 list(APPEND MODALITY_WORKLISTS_RESOURCES ${AUTOGENERATED_DIR}/ModalityWorklists.rc) | |
394 endif() | |
395 | |
396 add_library(ModalityWorklists SHARED | |
397 ${BOOST_SOURCES} | |
398 ${JSONCPP_SOURCES} | |
399 ${LIBICONV_SOURCES} | |
400 Plugins/Samples/Common/OrthancPluginCppWrapper.cpp | |
401 Plugins/Samples/ModalityWorklists/Plugin.cpp | |
402 ${MODALITY_WORKLISTS_RESOURCES} | |
403 ) | |
404 | |
405 set_target_properties( | |
406 ModalityWorklists PROPERTIES | |
407 VERSION ${ORTHANC_VERSION} | |
408 SOVERSION ${ORTHANC_VERSION} | |
409 ) | |
410 | |
411 install( | |
412 TARGETS ModalityWorklists | |
413 RUNTIME DESTINATION lib # Destination for Windows | |
414 LIBRARY DESTINATION share/orthanc/plugins # Destination for Linux | |
415 ) | |
416 endif() | |
417 | |
418 | |
419 | |
420 ##################################################################### | |
421 ## Build the companion tool to recover files compressed using Orthanc | |
422 ##################################################################### | |
423 | |
424 if (BUILD_RECOVER_COMPRESSED_FILE) | |
425 set(RECOVER_COMPRESSED_SOURCES | |
426 Resources/Samples/Tools/RecoverCompressedFile.cpp | |
427 ) | |
428 | |
429 if (${CMAKE_SYSTEM_NAME} STREQUAL "Windows") | |
430 execute_process( | |
431 COMMAND | |
432 ${PYTHON_EXECUTABLE} ${ORTHANC_ROOT}/Resources/WindowsResources.py | |
433 ${ORTHANC_VERSION} OrthancRecoverCompressedFile OrthancRecoverCompressedFile.exe | |
434 "Lightweight, RESTful DICOM server for medical imaging" | |
435 ERROR_VARIABLE Failure | |
436 OUTPUT_FILE ${AUTOGENERATED_DIR}/OrthancRecoverCompressedFile.rc | |
437 ) | |
438 | |
439 if (Failure) | |
440 message(FATAL_ERROR "Error while computing the version information: ${Failure}") | |
441 endif() | |
442 | |
443 list(APPEND RECOVER_COMPRESSED_SOURCES | |
444 ${AUTOGENERATED_DIR}/OrthancRecoverCompressedFile.rc | |
445 ) | |
446 endif() | |
447 | |
448 add_executable(OrthancRecoverCompressedFile ${RECOVER_COMPRESSED_SOURCES}) | |
449 | |
450 target_link_libraries(OrthancRecoverCompressedFile CoreLibrary) | |
451 | |
452 install( | |
453 TARGETS OrthancRecoverCompressedFile | |
454 RUNTIME DESTINATION bin | |
455 ) | |
456 endif() | |
457 | |
458 | |
459 | |
460 ##################################################################### | |
461 ## Generate the documentation if Doxygen is present | |
462 ##################################################################### | |
463 | |
464 find_package(Doxygen) | |
465 if (DOXYGEN_FOUND) | |
466 configure_file( | |
467 ${CMAKE_SOURCE_DIR}/Resources/Orthanc.doxygen | |
468 ${CMAKE_CURRENT_BINARY_DIR}/Orthanc.doxygen | |
469 @ONLY) | |
470 | |
471 configure_file( | |
472 ${CMAKE_SOURCE_DIR}/Resources/OrthancPlugin.doxygen | |
473 ${CMAKE_CURRENT_BINARY_DIR}/OrthancPlugin.doxygen | |
474 @ONLY) | |
475 | |
476 add_custom_target(doc | |
477 ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/Orthanc.doxygen | |
478 COMMENT "Generating internal documentation with Doxygen" VERBATIM | |
479 ) | |
480 | |
481 add_custom_command(TARGET Orthanc | |
482 POST_BUILD | |
483 COMMAND ${DOXYGEN_EXECUTABLE} ${CMAKE_CURRENT_BINARY_DIR}/OrthancPlugin.doxygen | |
484 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR} | |
485 COMMENT "Generating plugin documentation with Doxygen" VERBATIM | |
486 ) | |
487 | |
488 install( | |
489 DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/OrthancPluginDocumentation/doc/ | |
490 DESTINATION share/doc/orthanc/OrthancPlugin | |
491 ) | |
492 else() | |
493 message("Doxygen not found. The documentation will not be built.") | |
494 endif() | |
495 | |
496 | |
497 | |
498 ##################################################################### | |
499 ## Install the plugin SDK | |
500 ##################################################################### | |
501 | |
502 if (ENABLE_PLUGINS) | |
503 install( | |
504 FILES | |
505 Plugins/Include/orthanc/OrthancCPlugin.h | |
506 Plugins/Include/orthanc/OrthancCDatabasePlugin.h | |
507 DESTINATION include/orthanc | |
508 ) | |
509 endif() | |
510 | |
511 | |
512 | |
513 ##################################################################### | |
514 ## Prepare the "uninstall" target | |
515 ## http://www.cmake.org/Wiki/CMake_FAQ#Can_I_do_.22make_uninstall.22_with_CMake.3F | |
516 ##################################################################### | |
517 | |
518 configure_file( | |
519 "${CMAKE_CURRENT_SOURCE_DIR}/Resources/CMake/Uninstall.cmake.in" | |
520 "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake" | |
521 IMMEDIATE @ONLY) | |
522 | |
523 add_custom_target(uninstall | |
524 COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake) |