Mercurial > hg > orthanc-ohif

comparison Resources/Orthanc/CMake/DownloadOrthancFramework.cmake @ 0:39585ba26f20

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
initial commit
author Sebastien Jodogne <s.jodogne@gmail.com>
date Thu, 15 Jun 2023 09:48:46 +0200
parents
children 1bda8ea224de
comparison
equal deleted inserted replaced
-1:000000000000 0:39585ba26f20
1 # Orthanc - A Lightweight, RESTful DICOM Store
2 # Copyright (C) 2012-2016 Sebastien Jodogne, Medical Physics
3 # Department, University Hospital of Liege, Belgium
4 # Copyright (C) 2017-2023 Osimis S.A., Belgium
5 # Copyright (C) 2021-2023 Sebastien Jodogne, ICTEAM UCLouvain, Belgium
6 #
7 # This program is free software: you can redistribute it and/or
8 # modify it under the terms of the GNU Lesser General Public License
9 # as published by the Free Software Foundation, either version 3 of
10 # the License, or (at your option) any later version.
11 #
12 # This program is distributed in the hope that it will be useful, but
13 # WITHOUT ANY WARRANTY; without even the implied warranty of
14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
15 # Lesser General Public License for more details.
16 #
17 # You should have received a copy of the GNU Lesser General Public
18 # License along with this program. If not, see
19 # <http://www.gnu.org/licenses/>.
20
21
22
23 ##
24 ## Check whether the parent script sets the mandatory variables
25 ##
26
27 if (NOT DEFINED ORTHANC_FRAMEWORK_SOURCE OR
28 (NOT ORTHANC_FRAMEWORK_SOURCE STREQUAL "system" AND
29 NOT ORTHANC_FRAMEWORK_SOURCE STREQUAL "hg" AND
30 NOT ORTHANC_FRAMEWORK_SOURCE STREQUAL "web" AND
31 NOT ORTHANC_FRAMEWORK_SOURCE STREQUAL "archive" AND
32 NOT ORTHANC_FRAMEWORK_SOURCE STREQUAL "path"))
33 message(FATAL_ERROR "The variable ORTHANC_FRAMEWORK_SOURCE must be set to \"system\", \"hg\", \"web\", \"archive\" or \"path\"")
34 endif()
35
36
37 ##
38 ## Detection of the requested version
39 ##
40
41 if (ORTHANC_FRAMEWORK_SOURCE STREQUAL "hg" OR
42 ORTHANC_FRAMEWORK_SOURCE STREQUAL "archive" OR
43 ORTHANC_FRAMEWORK_SOURCE STREQUAL "web")
44 if (NOT DEFINED ORTHANC_FRAMEWORK_VERSION)
45 message(FATAL_ERROR "The variable ORTHANC_FRAMEWORK_VERSION must be set")
46 endif()
47
48 if (DEFINED ORTHANC_FRAMEWORK_MAJOR OR
49 DEFINED ORTHANC_FRAMEWORK_MINOR OR
50 DEFINED ORTHANC_FRAMEWORK_REVISION OR
51 DEFINED ORTHANC_FRAMEWORK_MD5)
52 message(FATAL_ERROR "Some internal variable has been set")
53 endif()
54
55 set(ORTHANC_FRAMEWORK_MD5 "")
56
57 if (NOT DEFINED ORTHANC_FRAMEWORK_BRANCH)
58 if (ORTHANC_FRAMEWORK_VERSION STREQUAL "mainline")
59 set(ORTHANC_FRAMEWORK_BRANCH "default")
60 set(ORTHANC_FRAMEWORK_MAJOR 999)
61 set(ORTHANC_FRAMEWORK_MINOR 999)
62 set(ORTHANC_FRAMEWORK_REVISION 999)
63
64 else()
65 set(ORTHANC_FRAMEWORK_BRANCH "Orthanc-${ORTHANC_FRAMEWORK_VERSION}")
66
67 set(RE "^([0-9]+)\\.([0-9]+)\\.([0-9]+)$")
68 string(REGEX REPLACE ${RE} "\\1" ORTHANC_FRAMEWORK_MAJOR ${ORTHANC_FRAMEWORK_VERSION})
69 string(REGEX REPLACE ${RE} "\\2" ORTHANC_FRAMEWORK_MINOR ${ORTHANC_FRAMEWORK_VERSION})
70 string(REGEX REPLACE ${RE} "\\3" ORTHANC_FRAMEWORK_REVISION ${ORTHANC_FRAMEWORK_VERSION})
71
72 if (NOT ORTHANC_FRAMEWORK_MAJOR MATCHES "^[0-9]+$" OR
73 NOT ORTHANC_FRAMEWORK_MINOR MATCHES "^[0-9]+$" OR
74 NOT ORTHANC_FRAMEWORK_REVISION MATCHES "^[0-9]+$")
75 message("Bad version of the Orthanc framework, assuming a pre-release: ${ORTHANC_FRAMEWORK_VERSION}")
76 set(ORTHANC_FRAMEWORK_MAJOR 999)
77 set(ORTHANC_FRAMEWORK_MINOR 999)
78 set(ORTHANC_FRAMEWORK_REVISION 999)
79 endif()
80
81 if (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.3.1")
82 set(ORTHANC_FRAMEWORK_MD5 "dac95bd6cf86fb19deaf4e612961f378")
83 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.3.2")
84 set(ORTHANC_FRAMEWORK_MD5 "d0ccdf68e855d8224331f13774992750")
85 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.4.0")
86 set(ORTHANC_FRAMEWORK_MD5 "81e15f34d97ac32bbd7d26e85698835a")
87 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.4.1")
88 set(ORTHANC_FRAMEWORK_MD5 "9b6f6114264b17ed421b574cd6476127")
89 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.4.2")
90 set(ORTHANC_FRAMEWORK_MD5 "d1ee84927dcf668e60eb5868d24b9394")
91 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.5.0")
92 set(ORTHANC_FRAMEWORK_MD5 "4429d8d9dea4ff6648df80ec3c64d79e")
93 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.5.1")
94 set(ORTHANC_FRAMEWORK_MD5 "099671538865e5da96208b37494d6718")
95 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.5.2")
96 set(ORTHANC_FRAMEWORK_MD5 "8867050f3e9a1ce6157c1ea7a9433b1b")
97 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.5.3")
98 set(ORTHANC_FRAMEWORK_MD5 "bf2f5ed1adb8b0fc5f10d278e68e1dfe")
99 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.5.4")
100 set(ORTHANC_FRAMEWORK_MD5 "404baef5d4c43e7c5d9410edda8ef5a5")
101 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.5.5")
102 set(ORTHANC_FRAMEWORK_MD5 "cfc437e0687ae4bd725fd93dc1f08bc4")
103 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.5.6")
104 set(ORTHANC_FRAMEWORK_MD5 "3c29de1e289b5472342947168f0105c0")
105 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.5.7")
106 set(ORTHANC_FRAMEWORK_MD5 "e1b76f01116d9b5d4ac8cc39980560e3")
107 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.5.8")
108 set(ORTHANC_FRAMEWORK_MD5 "82323e8c49a667f658a3639ea4dbc336")
109 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.6.0")
110 set(ORTHANC_FRAMEWORK_MD5 "eab428d6e53f61e847fa360bb17ebe25")
111 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.6.1")
112 set(ORTHANC_FRAMEWORK_MD5 "3971f5de96ba71dc9d3f3690afeaa7c0")
113 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.7.0")
114 set(ORTHANC_FRAMEWORK_MD5 "ce5f689e852b01d3672bd3d2f952a5ef")
115 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.7.1")
116 set(ORTHANC_FRAMEWORK_MD5 "3c171217f930abe80246997bdbcaf7cc")
117 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.7.2")
118 set(ORTHANC_FRAMEWORK_MD5 "328f94dcbd78c169655a13f7ad58a2c2")
119 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.7.3")
120 set(ORTHANC_FRAMEWORK_MD5 "3f1ba9502ec7c5449971d3b56087bcde")
121 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.7.4")
122 set(ORTHANC_FRAMEWORK_MD5 "19fcb7c21876af86546baa048a22c6c0")
123 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.8.0")
124 set(ORTHANC_FRAMEWORK_MD5 "f8ec7554ef5d23ea4ce474b1e8214de9")
125 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.8.1")
126 set(ORTHANC_FRAMEWORK_MD5 "db094f96399cbe8b9bbdbce34884c220")
127 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.8.2")
128 set(ORTHANC_FRAMEWORK_MD5 "8bfa10e66c9931e74111be0bfb1f4548")
129 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.9.0")
130 set(ORTHANC_FRAMEWORK_MD5 "cea0b02ce184671eaf1bd668beefbf28")
131 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.9.1")
132 set(ORTHANC_FRAMEWORK_MD5 "08eebc66ef93c3b40115c38501db5fbd")
133 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.9.2")
134 set(ORTHANC_FRAMEWORK_MD5 "3ea66c09f64aca990016683b6375734e")
135 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.9.3")
136 set(ORTHANC_FRAMEWORK_MD5 "9b86e6f00e03278293cd15643cc0233f")
137 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.9.4")
138 set(ORTHANC_FRAMEWORK_MD5 "6d5ca4a73ac7d42445041ca79de1624d")
139 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.9.5")
140 set(ORTHANC_FRAMEWORK_MD5 "10fc64de1254a095e5d3ed3931f0cfbb")
141 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.9.6")
142 set(ORTHANC_FRAMEWORK_MD5 "4b5d05683d747c29b2860ad79d11e62e")
143 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.9.7")
144 set(ORTHANC_FRAMEWORK_MD5 "c912bbb860d640d3ae3003b5c9698205")
145 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.10.0")
146 set(ORTHANC_FRAMEWORK_MD5 "8610c82d9153f22e929f2110f8f60279")
147 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.10.1")
148 set(ORTHANC_FRAMEWORK_MD5 "caf667fc5ea452b3d0c2f70bfd02599c")
149 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.11.0")
150 set(ORTHANC_FRAMEWORK_MD5 "962c4a4a706a2ef28b390d8515dd7091")
151 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.11.1")
152 set(ORTHANC_FRAMEWORK_MD5 "a39661c406adf22cf574fde290cf4bbf")
153 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.11.2")
154 set(ORTHANC_FRAMEWORK_MD5 "ede3de356493a8868545f8cb4b8bc8b5")
155 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.11.3")
156 set(ORTHANC_FRAMEWORK_MD5 "5c1b11009d782f248739919db6bf7f7a")
157 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "1.12.0")
158 set(ORTHANC_FRAMEWORK_MD5 "d32a0cde03b6eb603d8dd2b33d38bf1b")
159
160 # Below this point are development snapshots that were used to
161 # release some plugin, before an official release of the Orthanc
162 # framework was available. Here is the command to be used to
163 # generate a proper archive:
164 #
165 # $ hg archive /tmp/Orthanc-`hg id -i | sed 's/\+//'`.tar.gz
166 #
167 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "ae0e3fd609df")
168 # DICOMweb 1.1 (framework pre-1.6.0)
169 set(ORTHANC_FRAMEWORK_MD5 "7e09e9b530a2f527854f0b782d7e0645")
170 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "82652c5fc04f")
171 # Stone Web viewer 1.0 (framework pre-1.8.1)
172 set(ORTHANC_FRAMEWORK_MD5 "d77331d68917e66a3f4f9b807bbdab7f")
173 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "4a3ba4bf4ba7")
174 # PostgreSQL 3.3 (framework pre-1.8.2)
175 set(ORTHANC_FRAMEWORK_MD5 "2d82bddf06f9cfe82095495cb3b8abde")
176 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "23ad1b9c7800")
177 # For "Toolbox::ReadJson()" and "Toolbox::Write{...}Json()" (pre-1.9.0)
178 set(ORTHANC_FRAMEWORK_MD5 "9af92080e57c60dd288eba46ce606c00")
179 elseif (ORTHANC_FRAMEWORK_VERSION STREQUAL "b2e08d83e21d")
180 # WSI 1.1 (framework pre-1.10.0), to remove "-std=c++11"
181 set(ORTHANC_FRAMEWORK_MD5 "2eaa073cbb4b44ffba199ad93393b2b1")
182 endif()
183 endif()
184 endif()
185
186 elseif (ORTHANC_FRAMEWORK_SOURCE STREQUAL "path")
187 message("Using the Orthanc framework from a path of the filesystem. Assuming mainline version.")
188 set(ORTHANC_FRAMEWORK_MAJOR 999)
189 set(ORTHANC_FRAMEWORK_MINOR 999)
190 set(ORTHANC_FRAMEWORK_REVISION 999)
191 endif()
192
193
194
195 ##
196 ## Detection of the third-party software
197 ##
198
199 if (ORTHANC_FRAMEWORK_SOURCE STREQUAL "hg")
200 find_program(ORTHANC_FRAMEWORK_HG hg)
201
202 if (${ORTHANC_FRAMEWORK_HG} MATCHES "ORTHANC_FRAMEWORK_HG-NOTFOUND")
203 message(FATAL_ERROR "Please install Mercurial")
204 endif()
205 endif()
206
207
208 if (ORTHANC_FRAMEWORK_SOURCE STREQUAL "archive" OR
209 ORTHANC_FRAMEWORK_SOURCE STREQUAL "web")
210 if ("${CMAKE_HOST_SYSTEM_NAME}" STREQUAL "Windows")
211 find_program(ORTHANC_FRAMEWORK_7ZIP 7z
212 PATHS
213 "$ENV{ProgramFiles}/7-Zip"
214 "$ENV{ProgramW6432}/7-Zip"
215 )
216
217 if (${ORTHANC_FRAMEWORK_7ZIP} MATCHES "ORTHANC_FRAMEWORK_7ZIP-NOTFOUND")
218 message(FATAL_ERROR "Please install the '7-zip' software (http://www.7-zip.org/)")
219 endif()
220
221 else()
222 find_program(ORTHANC_FRAMEWORK_TAR tar)
223 if (${ORTHANC_FRAMEWORK_TAR} MATCHES "ORTHANC_FRAMEWORK_TAR-NOTFOUND")
224 message(FATAL_ERROR "Please install the 'tar' package")
225 endif()
226 endif()
227 endif()
228
229
230
231 ##
232 ## Case of the Orthanc framework specified as a path on the filesystem
233 ##
234
235 if (ORTHANC_FRAMEWORK_SOURCE STREQUAL "path")
236 if (NOT DEFINED ORTHANC_FRAMEWORK_ROOT OR
237 ORTHANC_FRAMEWORK_ROOT STREQUAL "")
238 message(FATAL_ERROR "The variable ORTHANC_FRAMEWORK_ROOT must provide the path to the sources of Orthanc")
239 endif()
240
241 if (NOT EXISTS ${ORTHANC_FRAMEWORK_ROOT})
242 message(FATAL_ERROR "Non-existing directory: ${ORTHANC_FRAMEWORK_ROOT}")
243 endif()
244 endif()
245
246
247
248 ##
249 ## Case of the Orthanc framework cloned using Mercurial
250 ##
251
252 if (ORTHANC_FRAMEWORK_SOURCE STREQUAL "hg")
253 if (NOT STATIC_BUILD AND NOT ALLOW_DOWNLOADS)
254 message(FATAL_ERROR "CMake is not allowed to download from Internet. Please set the ALLOW_DOWNLOADS option to ON")
255 endif()
256
257 set(ORTHANC_ROOT ${CMAKE_BINARY_DIR}/orthanc)
258
259 if (EXISTS ${ORTHANC_ROOT})
260 message("Updating the Orthanc source repository using Mercurial")
261 execute_process(
262 COMMAND ${ORTHANC_FRAMEWORK_HG} pull
263 WORKING_DIRECTORY ${ORTHANC_ROOT}
264 RESULT_VARIABLE Failure
265 )
266 else()
267 message("Forking the Orthanc source repository using Mercurial")
268 execute_process(
269 COMMAND ${ORTHANC_FRAMEWORK_HG} clone "https://hg.orthanc-server.com/orthanc/"
270 WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
271 RESULT_VARIABLE Failure
272 )
273 endif()
274
275 if (Failure OR NOT EXISTS ${ORTHANC_ROOT})
276 message(FATAL_ERROR "Cannot fork the Orthanc repository")
277 endif()
278
279 message("Setting branch of the Orthanc repository to: ${ORTHANC_FRAMEWORK_BRANCH}")
280
281 execute_process(
282 COMMAND ${ORTHANC_FRAMEWORK_HG} update -c ${ORTHANC_FRAMEWORK_BRANCH}
283 WORKING_DIRECTORY ${ORTHANC_ROOT}
284 RESULT_VARIABLE Failure
285 )
286
287 if (Failure)
288 message(FATAL_ERROR "Error while running Mercurial")
289 endif()
290 endif()
291
292
293
294 ##
295 ## Case of the Orthanc framework provided as a source archive on the
296 ## filesystem
297 ##
298
299 if (ORTHANC_FRAMEWORK_SOURCE STREQUAL "archive")
300 if (NOT DEFINED ORTHANC_FRAMEWORK_ARCHIVE OR
301 ORTHANC_FRAMEWORK_ARCHIVE STREQUAL "")
302 message(FATAL_ERROR "The variable ORTHANC_FRAMEWORK_ARCHIVE must provide the path to the sources of Orthanc")
303 endif()
304 endif()
305
306
307
308 ##
309 ## Case of the Orthanc framework downloaded from the Web
310 ##
311
312 if (ORTHANC_FRAMEWORK_SOURCE STREQUAL "web")
313 if (DEFINED ORTHANC_FRAMEWORK_URL)
314 string(REGEX REPLACE "^.*/" "" ORTHANC_FRAMEMORK_FILENAME "${ORTHANC_FRAMEWORK_URL}")
315 else()
316 # Default case: Download from the official Web site
317 set(ORTHANC_FRAMEMORK_FILENAME Orthanc-${ORTHANC_FRAMEWORK_VERSION}.tar.gz)
318 set(ORTHANC_FRAMEWORK_URL "https://orthanc.uclouvain.be/third-party-downloads/orthanc-framework/${ORTHANC_FRAMEMORK_FILENAME}")
319 endif()
320
321 set(ORTHANC_FRAMEWORK_ARCHIVE "${CMAKE_SOURCE_DIR}/ThirdPartyDownloads/${ORTHANC_FRAMEMORK_FILENAME}")
322
323 if (NOT EXISTS "${ORTHANC_FRAMEWORK_ARCHIVE}")
324 if (NOT STATIC_BUILD AND NOT ALLOW_DOWNLOADS)
325 message(FATAL_ERROR "CMake is not allowed to download from Internet. Please set the ALLOW_DOWNLOADS option to ON")
326 endif()
327
328 message("Downloading: ${ORTHANC_FRAMEWORK_URL}")
329
330 file(DOWNLOAD
331 "${ORTHANC_FRAMEWORK_URL}" "${ORTHANC_FRAMEWORK_ARCHIVE}"
332 SHOW_PROGRESS EXPECTED_MD5 "${ORTHANC_FRAMEWORK_MD5}"
333 TIMEOUT 60
334 INACTIVITY_TIMEOUT 60
335 )
336 else()
337 message("Using local copy of: ${ORTHANC_FRAMEWORK_URL}")
338 endif()
339 endif()
340
341
342
343
344 ##
345 ## Uncompressing the Orthanc framework, if it was retrieved from a
346 ## source archive on the filesystem, or from the official Web site
347 ##
348
349 if (ORTHANC_FRAMEWORK_SOURCE STREQUAL "archive" OR
350 ORTHANC_FRAMEWORK_SOURCE STREQUAL "web")
351
352 if (NOT DEFINED ORTHANC_FRAMEWORK_ARCHIVE OR
353 NOT DEFINED ORTHANC_FRAMEWORK_VERSION OR
354 NOT DEFINED ORTHANC_FRAMEWORK_MD5)
355 message(FATAL_ERROR "Internal error")
356 endif()
357
358 if (ORTHANC_FRAMEWORK_MD5 STREQUAL "")
359 message(FATAL_ERROR "Unknown release of Orthanc: ${ORTHANC_FRAMEWORK_VERSION}")
360 endif()
361
362 file(MD5 ${ORTHANC_FRAMEWORK_ARCHIVE} ActualMD5)
363
364 if (NOT "${ActualMD5}" STREQUAL "${ORTHANC_FRAMEWORK_MD5}")
365 message(FATAL_ERROR "The MD5 hash of the Orthanc archive is invalid: ${ORTHANC_FRAMEWORK_ARCHIVE}")
366 endif()
367
368 set(ORTHANC_ROOT "${CMAKE_BINARY_DIR}/Orthanc-${ORTHANC_FRAMEWORK_VERSION}")
369
370 if (NOT IS_DIRECTORY "${ORTHANC_ROOT}")
371 if (NOT ORTHANC_FRAMEWORK_ARCHIVE MATCHES ".tar.gz$")
372 message(FATAL_ERROR "Archive should have the \".tar.gz\" extension: ${ORTHANC_FRAMEWORK_ARCHIVE}")
373 endif()
374
375 message("Uncompressing: ${ORTHANC_FRAMEWORK_ARCHIVE}")
376
377 if ("${CMAKE_HOST_SYSTEM_NAME}" STREQUAL "Windows")
378 # How to silently extract files using 7-zip
379 # http://superuser.com/questions/331148/7zip-command-line-extract-silently-quietly
380
381 execute_process(
382 COMMAND ${ORTHANC_FRAMEWORK_7ZIP} e -y ${ORTHANC_FRAMEWORK_ARCHIVE}
383 WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
384 RESULT_VARIABLE Failure
385 OUTPUT_QUIET
386 )
387
388 if (Failure)
389 message(FATAL_ERROR "Error while running the uncompression tool")
390 endif()
391
392 get_filename_component(TMP_FILENAME "${ORTHANC_FRAMEWORK_ARCHIVE}" NAME)
393 string(REGEX REPLACE ".gz$" "" TMP_FILENAME2 "${TMP_FILENAME}")
394
395 execute_process(
396 COMMAND ${ORTHANC_FRAMEWORK_7ZIP} x -y ${TMP_FILENAME2}
397 WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
398 RESULT_VARIABLE Failure
399 OUTPUT_QUIET
400 )
401
402 else()
403 execute_process(
404 COMMAND sh -c "${ORTHANC_FRAMEWORK_TAR} xfz ${ORTHANC_FRAMEWORK_ARCHIVE}"
405 WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
406 RESULT_VARIABLE Failure
407 )
408 endif()
409
410 if (Failure)
411 message(FATAL_ERROR "Error while running the uncompression tool")
412 endif()
413
414 if (NOT IS_DIRECTORY "${ORTHANC_ROOT}")
415 message(FATAL_ERROR "The Orthanc framework was not uncompressed at the proper location. Check the CMake instructions.")
416 endif()
417 endif()
418 endif()
419
420
421
422 ##
423 ## Determine the path to the sources of the Orthanc framework
424 ##
425
426 if (ORTHANC_FRAMEWORK_SOURCE STREQUAL "archive" OR
427 ORTHANC_FRAMEWORK_SOURCE STREQUAL "hg" OR
428 ORTHANC_FRAMEWORK_SOURCE STREQUAL "web")
429 if (NOT DEFINED ORTHANC_ROOT OR
430 NOT DEFINED ORTHANC_FRAMEWORK_MAJOR OR
431 NOT DEFINED ORTHANC_FRAMEWORK_MINOR OR
432 NOT DEFINED ORTHANC_FRAMEWORK_REVISION)
433 message(FATAL_ERROR "Internal error in the DownloadOrthancFramework.cmake file")
434 endif()
435
436 unset(ORTHANC_FRAMEWORK_ROOT CACHE)
437
438 if ("${ORTHANC_FRAMEWORK_MAJOR}.${ORTHANC_FRAMEWORK_MINOR}.${ORTHANC_FRAMEWORK_REVISION}" VERSION_LESS "1.7.2")
439 set(ORTHANC_FRAMEWORK_ROOT "${ORTHANC_ROOT}/Core" CACHE
440 STRING "Path to the Orthanc framework source directory")
441 set(ENABLE_PLUGINS_VERSION_SCRIPT OFF)
442 else()
443 set(ORTHANC_FRAMEWORK_ROOT "${ORTHANC_ROOT}/OrthancFramework/Sources" CACHE
444 STRING "Path to the Orthanc framework source directory")
445 endif()
446
447 unset(ORTHANC_ROOT)
448 endif()
449
450 if (NOT ORTHANC_FRAMEWORK_SOURCE STREQUAL "system")
451 if (NOT EXISTS ${ORTHANC_FRAMEWORK_ROOT}/OrthancException.h OR
452 NOT EXISTS ${ORTHANC_FRAMEWORK_ROOT}/../Resources/CMake/OrthancFrameworkParameters.cmake)
453 message(FATAL_ERROR "Directory not containing the source code of the Orthanc framework: ${ORTHANC_FRAMEWORK_ROOT}")
454 endif()
455 endif()
456
457
458
459 ##
460 ## Case of the Orthanc framework installed as a shared library in a
461 ## GNU/Linux distribution (typically Debian). New in Orthanc 1.7.2.
462 ##
463
464 if (ORTHANC_FRAMEWORK_SOURCE STREQUAL "system")
465 set(ORTHANC_FRAMEWORK_LIBDIR "" CACHE PATH "")
466 set(ORTHANC_FRAMEWORK_USE_SHARED ON CACHE BOOL "Whether to use the shared library or the static library")
467 set(ORTHANC_FRAMEWORK_ADDITIONAL_LIBRARIES "" CACHE STRING "Additional libraries to link against, separated by whitespaces, typically needed if using the static library (a common minimal value is \"boost_filesystem boost_iostreams boost_locale boost_regex boost_thread jsoncpp pugixml uuid\")")
468
469 if (CMAKE_SYSTEM_NAME STREQUAL "Windows" AND
470 CMAKE_COMPILER_IS_GNUCXX) # MinGW
471 set(DYNAMIC_MINGW_STDLIB ON) # Disable static linking against libc (to throw exceptions)
472 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
473 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
474 endif()
475
476 include(CheckIncludeFile)
477 include(CheckIncludeFileCXX)
478 include(FindPythonInterp)
479 include(${CMAKE_CURRENT_LIST_DIR}/Compiler.cmake)
480 include(${CMAKE_CURRENT_LIST_DIR}/DownloadPackage.cmake)
481 include(${CMAKE_CURRENT_LIST_DIR}/AutoGeneratedCode.cmake)
482 set(EMBED_RESOURCES_PYTHON ${CMAKE_CURRENT_LIST_DIR}/EmbedResources.py)
483
484 if (ORTHANC_FRAMEWORK_USE_SHARED)
485 list(GET CMAKE_FIND_LIBRARY_PREFIXES 0 Prefix)
486 list(GET CMAKE_FIND_LIBRARY_SUFFIXES 0 Suffix)
487 else()
488 list(GET CMAKE_FIND_LIBRARY_PREFIXES 0 Prefix)
489 list(GET CMAKE_FIND_LIBRARY_SUFFIXES 1 Suffix)
490 endif()
491
492 # The "OrthancFramework" library must be the first one to be included
493 if ("${ORTHANC_FRAMEWORK_LIBDIR}" STREQUAL "")
494 set(ORTHANC_FRAMEWORK_LIBRARIES ${Prefix}OrthancFramework${Suffix})
495 else ()
496 set(ORTHANC_FRAMEWORK_LIBRARIES ${ORTHANC_FRAMEWORK_LIBDIR}/${Prefix}OrthancFramework${Suffix})
497 endif()
498
499 if (NOT ORTHANC_FRAMEWORK_ADDITIONAL_LIBRARIES STREQUAL "")
500 # https://stackoverflow.com/a/5272993/881731
501 string(REPLACE " " ";" tmp ${ORTHANC_FRAMEWORK_ADDITIONAL_LIBRARIES})
502 list(APPEND ORTHANC_FRAMEWORK_LIBRARIES ${tmp})
503 endif()
504
505 # Look for the version of the mandatory dependency JsonCpp (cf. JsonCppConfiguration.cmake)
506 if (CMAKE_CROSSCOMPILING)
507 set(JSONCPP_INCLUDE_DIR ${ORTHANC_FRAMEWORK_ROOT}/..)
508 else()
509 find_path(JSONCPP_INCLUDE_DIR json/reader.h
510 ${ORTHANC_FRAMEWORK_ROOT}/..
511 /usr/include/jsoncpp
512 /usr/local/include/jsoncpp
513 )
514 endif()
515
516 message("JsonCpp include dir: ${JSONCPP_INCLUDE_DIR}")
517 include_directories(${JSONCPP_INCLUDE_DIR})
518
519 CHECK_INCLUDE_FILE_CXX(${JSONCPP_INCLUDE_DIR}/json/reader.h HAVE_JSONCPP_H)
520 if (NOT HAVE_JSONCPP_H)
521 message(FATAL_ERROR "Please install the libjsoncpp-dev package")
522 endif()
523
524 # Look for Orthanc framework shared library
525 include(CheckCXXSymbolExists)
526
527 if ("${CMAKE_SYSTEM_NAME}" STREQUAL "Windows")
528 set(ORTHANC_FRAMEWORK_INCLUDE_DIR ${ORTHANC_FRAMEWORK_ROOT})
529 else()
530 find_path(ORTHANC_FRAMEWORK_INCLUDE_DIR OrthancFramework.h
531 /usr/include/orthanc-framework
532 /usr/local/include/orthanc-framework
533 ${ORTHANC_FRAMEWORK_ROOT}
534 )
535 endif()
536
537 if (${ORTHANC_FRAMEWORK_INCLUDE_DIR} STREQUAL "ORTHANC_FRAMEWORK_INCLUDE_DIR-NOTFOUND")
538 message(FATAL_ERROR "Cannot locate the OrthancFramework.h header")
539 endif()
540
541 message("Orthanc framework include dir: ${ORTHANC_FRAMEWORK_INCLUDE_DIR}")
542 include_directories(${ORTHANC_FRAMEWORK_INCLUDE_DIR})
543
544 if (ORTHANC_FRAMEWORK_USE_SHARED)
545 set(CMAKE_REQUIRED_INCLUDES "${ORTHANC_FRAMEWORK_INCLUDE_DIR}")
546 set(CMAKE_REQUIRED_LIBRARIES "${ORTHANC_FRAMEWORK_LIBRARIES}")
547
548 check_cxx_symbol_exists("Orthanc::InitializeFramework" "OrthancFramework.h" HAVE_ORTHANC_FRAMEWORK)
549 if (NOT HAVE_ORTHANC_FRAMEWORK)
550 message(FATAL_ERROR "Cannot find the Orthanc framework")
551 endif()
552
553 unset(CMAKE_REQUIRED_INCLUDES)
554 unset(CMAKE_REQUIRED_LIBRARIES)
555 endif()
556 endif()